Как найти ключ продукта Windows 10 на вашем компьютере

Очень важно иметь ключ продукта операционной системы Windows 10, которая установлена на вашем компьютере или ноутбуке. Без ключа продукта вы не сможете активировать копию Windows или обновить ОС Windows 10. Ключ продукта — это 25-значный буквенно-цифровой код, который используется для активации любой версии Windows. В зависимости от версии и категории вашей копии ОС Windows ключ продукта может быть разным.

Вы можете получить копию Windows четырьмя различными способами.

  • У авторизованного продавца.
  • Предустановленная Windows 10 в ноутбуке, вы можете получить ее с ноутбуками HP или другими ноутбуками при покупке ноутбука.
  • Цифровая копия Windows 10, которая очень доступна на сайте Microsoft.
  • Получите цифровую лицензию при переходе на Windows 10 с более ранних версий, например, Windows 7, Windows 8 и т. д. Имейте в виду, что эти копии Windows не поставляются с ключом продукта, а только с цифровой лицензией.
  • Поскольку ключ является жизненно важным, его следует записать для дальнейшего использования. Но возникает вопрос, как найти ключ продукта Windows 10 в установленной и активированной копии ОС Windows 10? Вы можете получить его либо с помощью PowerShell Windows 10, либо с помощью специального программного обеспечения.

    Как найти ключ продукта в Windows 10

    Способ 1: Получение ключа продукта без программного обеспечения

    Откройте блокнот.

    Скопируйте код ниже и вставьте его туда.

    Option Explicit
    
    Dim objshell,path,DigitalID, Result
    Set objshell = CreateObject("WScript.Shell")
    'Set registry key path
    Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
    'Registry key value
    DigitalID = objshell.RegRead(Path & "DigitalProductId")
    Dim ProductName,ProductID,ProductKey,ProductData
    'Get ProductName, ProductID, ProductKey
    ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
    ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
    ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
    ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
    'Show messbox if save to a file
    If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
       Save ProductData
    End If
    
    
    
    'Convert binary to chars
    Function ConvertToKey(Key)
        Const KeyOffset = 52
        Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
        'Check if OS is Windows 8
        isWin8 = (Key(66) \ 6) And 1
        Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
        i = 24
        Maps = "BCDFGHJKMPQRTVWXY2346789"
        Do
               Current= 0
            j = 14
            Do
               Current = Current* 256
               Current = Key(j + KeyOffset) + Current
               Key(j + KeyOffset) = (Current \ 24)
               Current=Current Mod 24
                j = j -1
            Loop While j >= 0
            i = i -1
            KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
            Last = Current
        Loop While i >= 0
        keypart1 = Mid(KeyOutput, 2, Last)
        insert = "N"
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then KeyOutput = insert & KeyOutput
        ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
       
       
    End Function
    'Save data to a file
    Function Save(Data)
        Dim fso, fName, txt,objshell,UserName
        Set objshell = CreateObject("wscript.shell")
        'Get current user name
        UserName = objshell.ExpandEnvironmentStrings("%UserName%")
        'Create a text file on desktop
        fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
        Set fso = CreateObject("Scripting.FileSystemObject")
        Set txt = fso.CreateTextFile(fName)
        txt.Writeline Data
        txt.Close
    End Function
    

    Сохраните файл как файл .vbs. Или дайте файлу имя типаWindowsProductKey.vbs и сохраните его на рабочем столе Windows.

    Рекомендуем:  Устранение: Как получить помощь в Windows 10 Вирус продолжает выскакивать автоматически

    Дважды щелкните файл, чтобы найти ключ продукта вашей текущей ОС Windows.

    Источник кода: Форум Microsoft

    Метод 2: Найти и восстановить потерянный ключ продукта Windows 10 с помощью программы ProductKey

    Если вы потеряли ключ продукта Windows и хотите восстановить потерянный CD-ключ для вашей текущей ОС, то программа ProductKey от Nirsoft может удовлетворить ваши потребности. Просто скачайте программу с сайта и запустите ее на своем компьютере. Программа отобразит информацию о ключе продукта в собственном всплывающем окне.

    В этом руководстве я описываю методы извлечения ключа продукта Windows 10 из установленной ОС. Резервная копия ключа продукта полезна для обновления ОС Windows 10 и ее компонентов. Если вы не знаете, как перенести установку Windows на другой компьютер, то ключ продукта необходим для активации Windows после свежей установки.

    Оцените статью
    Gud-PC